var playerloader:Loader = new Loader();
playerloader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
addChild(playerloader);

var playerloader:Loader = new Loader();
var player:Object;
playerloader.contentLoaderInfo.addEventListener(Event.COMPLETE, onPlayerLoadComplete);
function onPlayerLoadComplete(event:Event):void
{
addChild(playerloader);
playerloader.content.addEventListener("onReady", startVideos);
}
 
function startVideos(event:Event):void
{
player = playerloader.content;
player.loadVideo("videoid", 0, "medium");
}

package 
{
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.net.URLRequest;
	import flash.utils.Dictionary;
	import flash.desktop.Clipboard;
	import flash.desktop.ClipboardFormats;
 
	/**
	 * Youtube
	 * @author Eder Lima
	 * @author url http://www.ederlima.com.br
	 * @author twitter http://www.twitter.com/ederlemon
	 * @copy FlashPedia - http://www.flashpedia.com.br
	 * 
	 * Este player utilizando a Video Player Api do Youtube tem por
	 * objetivo ensinar aos developers iniciantes os conceitos básicos de 
	 * interação com a nova API AS3 do player do youtube.
	 * 
	 * Se reutilizar, por favor, mantenha os créditos.
	 *
	 */
	public class Youtube extends Sprite
	{
		//criando o objeto que vai receber o player
		private var player:Object;
		//criando o objeto Loader que vai carregar o player
		private var playerloader:Loader = new Loader();		
		//criando um dicionário para tratar as respostas do status da reprodução
		private var sd:Dictionary = new Dictionary();
		//criando as variáveis utilizadas na amostragem do tempo
		//minutos
		private var m:int;
		//segundos
		private var s:int;
		//variável string para uso temporário no arredondamento do tempo
		private var rt:String;
		//boleano que informa se está ocorrendo seek
		private var seeking:Boolean = false;
 
		//Construtor da DocumentClass	
		//Excutado automaticamente ao iniciar o filme
		public function Youtube()
		{
			//Carregando o player assim que adicionado ao palco
			addEventListener(Event.ADDED_TO_STAGE, loadPlayer);
		}
		//Carregando o player
		private function loadPlayer(event:Event):void
		{
			//removendo o evento para início do filme
			removeEventListener(Event.ADDED_TO_STAGE, loadPlayer);
			//configurando o ambiente
			configure();
			//adicionando uma função ao evento "complete" do loader
			playerloader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadPlayerComplete);
			//carregando a partir da url da API
			playerloader.load(new URLRequest("http://www.youtube.com/apiplayer?version=3"));
		}
		//Configurando o ambiente
		private function configure():void
		{
			//Populando o dicionário com as mensagens de status para cada código (de -1 a 5)
			sd[-1] = "Waiting...";
			sd[0] = "Ended";
			sd[1] = "Playing...";
			sd[2] = "Paused...";
			sd[3] = "Bufering...";
			sd[5] = "Cue...";
			//Adicionando o handcursor nos botões de interação
			playbutton.buttonMode = true;
			pausebutton.buttonMode = true;
			stopbutton.buttonMode = true;
			gobutton.buttonMode = true;
			seekbar.tracker.buttonMode = true;
			urlbutton.buttonMode = true;
			embedbutton.buttonMode = true;
		}
		//Função do evento "complete" do loader
		private function loadPlayerComplete(event:Event):void
		{
			//Adiciona o player no container
			container.addChild(playerloader);
			//Adiciona uma função ao evento "onReady" que é disparado pelo player 
			//Esse evento é quem dá início ao carregamento e reprodução do primeiro filme
			playerloader.content.addEventListener("onReady", onPlayerReady);
			//Adiciona uma função ao evento de Erro
			playerloader.content.addEventListener("onError", onPlayerError);
			//Adiciona uma função ao evento de Status
			playerloader.content.addEventListener("onStateChange", onPlayerStateChange);
			//Adiciona uma função ao evento de mudança de qualidade 
			playerloader.content.addEventListener("onPlaybackQualityChange", onVideoPlaybackQualityChange);
		}
		//Função do evento "onReady" do player
		private function onPlayerReady(event:Event):void
		{
			//Informando no status 
			ps.text = "Player ready...";
			//recebendo o conteúdo do playerloader como objeto (para que possa executar métodos)
			player = playerloader.content;		
			//Iniializando a função que carrega o primeiro vídeo
			loadVideo();
			//Adicionando funções de controle aos botões 'play', 'pause', 'stop' e 'go'
			playbutton.addEventListener(MouseEvent.CLICK, playByClick);
			pausebutton.addEventListener(MouseEvent.CLICK, pauseByClick);
			stopbutton.addEventListener(MouseEvent.CLICK, stopByClick);
			gobutton.addEventListener(MouseEvent.CLICK, loadByClick);
			//Adiciona a função de seek ao tracker de progresso
			seekbar.tracker.addEventListener(MouseEvent.MOUSE_DOWN, seekStart);
			seekbar.tracker.addEventListener(MouseEvent.MOUSE_UP, seekDragStop);
			//Adiciona a função que copia a url ou o embed code para a área de transferência
			urlbutton.addEventListener(MouseEvent.CLICK, copyUrl);
			embedbutton.addEventListener(MouseEvent.CLICK, copyEmbed);
 
		}
		/*
		 * Observações gerais
		 * Reparem que os métodos que controlam o player são todos disparados usando: player.método()
		 * Isso acontece porque recebemos o conteúdo do loader, ou seja, o player carregado, como objeto,
		 * isso nos permite executar os métodos através da instância desse objeto, ex: player.playVideo();
		 */
		//Play por clique
		private function playByClick(event:MouseEvent):void
		{
			player.playVideo();
		}
		//Pause por clique
		private function pauseByClick(event:MouseEvent):void
		{
			player.pauseVideo();
		}
		//Stop por clique
		private function stopByClick(event:MouseEvent):void
		{
			player.stopVideo();
		}
		//SeekStart adiciona um evento "mouse_move", que caso o mouse esteja numa posição menor que 
		//a escala da barra de progresso de download do vídeo, permita que ele faça o seek
		private function seekStart(event:MouseEvent):void
		{
			seeking = true;
			event.target.addEventListener(MouseEvent.MOUSE_MOVE, seekDrag);
		}
		//SeekDrag posiciona o cursor sobre a barra de progresso para o seek
		private function seekDrag(event:MouseEvent):void
		{
			//se a posição for menor que a escala da barra de download o tracker segue
			if (seekbar.mouseX <= int(player.getVideoBytesLoaded() / player.getVideoBytesTotal() * 100) * 400 / 100)
			{
				event.target.x = seekbar.mouseX;
			}
			//se não o tracker volta a posição atual de execução
			else 
			{
				event.target.removeEventListener(MouseEvent.MOUSE_MOVE, seekDrag);
				seeking = false;
			}
		}
		//SeekStop encerra o arraste ao soltar do mouse
		private function seekDragStop(event:MouseEvent):void
		{
			player.seekTo(int((event.target.x / 400 * 100) * player.getDuration() / 100 ), false);
			seeking = false;
		}
		//Copiando a url para a área de transferência
		private function copyUrl(event:MouseEvent):void
		{
			Clipboard.generalClipboard.clear();
			Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, player.getVideoUrl());
			clip.text = "Video URL copied...";
		}
		//Copiando o embed code para a área de transferência (ele só é retornado após a segunda mudança de estágio)
		private function copyEmbed(event:MouseEvent):void
		{
			Clipboard.generalClipboard.clear();
			Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, player.getVideoEmbedCode());
			clip.text = "Embed Code copied...";
		}
		//Tratando os eventos do player
		//Erro
		private function onPlayerError(event:Event):void
		{
			ps.text = Object(event).data;
		}
		//Mudança de status
		private function onPlayerStateChange(event:Event):void
		{
			//Informando na caixa de texto o valor referente a chave no dicionário
			ps.text = sd[Object(event).data];
		}
		//Mundaça de qualidade
		private function onVideoPlaybackQualityChange(event:Event):void
		{
			vq.text = Object(event).data;
		}
		//Controlando o Player
		//Carregando o vídeo
		private function loadVideo():void
		{
			//Definindo o tamanho do player
			player.setSize(400, 300);
			//Carregando um vídeo através da ID com qualidade média
			//player.loadVideoById("IthnIUXEEl4", 0, "medium");
			player.cueVideoById("IthnIUXEEl4", 0, "medium");
			//Adicionando um evento para calcular o tempo atual e o carregamento
			addEventListener(Event.ENTER_FRAME, traceTime);
		}
		//Carregando o vídeo ao clique em "Go"
		private function loadByClick(event:MouseEvent):void
		{
			//Parando vídeo atual
			player.stopVideo();
			//Removendo função do evento 'enterFrame' que calcula o tempo
			removeEventListener(Event.ENTER_FRAME, traceTime);
			//Carregando um novo vídeo utilizando a ID digitada na caixa de texto
			//Não foi feito nenhuma função para tratar o campo vazio
			player.loadVideoById(videoid.text, 0);
			//Readicionando o evento para calcular o tempo
			addEventListener(Event.ENTER_FRAME, traceTime);
		}
		//Funções auxiiliares
		//Calculando o tempo e o carregamento
		private function traceTime(event:Event):void
		{
			//Informando o tempo atual
			actual.text = convertDigits(player.getCurrentTime());
			//Informando o tempo total
			total.text = convertDigits(player.getDuration());
			//Informando a quantidade de bytes do vídeo
			bt.text = String(int(player.getVideoBytesTotal() / 1024) + "Kb");
			//Informando o percentual carregado em streamming
			bl.text = String(int(player.getVideoBytesLoaded() / player.getVideoBytesTotal() * 100) + "%");
			//Calculando a escala da barra de progresso do download do vídeo
			if (isNaN(player.getVideoBytesLoaded() / player.getVideoBytesTotal()))
			{
				seekbar.loadedbar.scaleX = 0;
			}
			else
			{
				seekbar.loadedbar.scaleX = player.getVideoBytesLoaded() / player.getVideoBytesTotal();
			}
			//Movendo o tracker conforme o progresso da execução (se não estiver arrastando)
			!seeking ? seekbar.tracker.x = int(player.getCurrentTime() / player.getDuration() * 100) * 400 / 100 : void;
 
		}
		//Convertendo o tempo de segundos ex: 190 para minutos e segundos em string 03:10
		private function convertDigits(value:Number):String
		{
			m = int(value / 60);
			s = int(value % 60);
			return addZero(m) + ":" + addZero(s);
		}
		//adicionando Zero 1 -> 01
		private function addZero(value:int):String
		{
			value <= 9 ? rt = String("0" + value) : rt = String(value);
			return rt;
		}
	}
 
}